大大-蓝奏云直链一键解析软件

此软件使用易语言编写而成，会报毒，建议使用沙箱或关闭杀毒软件运行即可！

使用方法

把需要解析的蓝奏云链接粘贴在解析链接编辑框里，选择解析等待几秒钟即可会解析出来，软件暂不支持密码解析链接，需要添加无密码解析链接才可以解析成功。

易语言代码

.版本 2
.支持库 spec

.程序集 窗口程序集_启动窗口

.子程序 _按钮1_被单击

.如果 (编辑框1.内容 ＝ “”)
    信息框 (“请输入蓝奏云分享链接”, #警告图标, “提示”, )
.否则
    编辑框2.内容 ＝ 解析链接 (编辑框1.内容, )

.如果结束


.子程序 解析链接, 文本型, 公开, 成功返回文件直链,失败返回空
.参数 待解析链接, 文本型, , 蓝奏云文件下载地址
.参数 错误次数, 整数型, 可空, 获取失败重试次数,默认5次,基本一次就OK了
.局部变量 返回文本, 文本型
.局部变量 src, 文本型
.局部变量 sign, 文本型
.局部变量 url, 文本型
.局部变量 域名, 文本型
.局部变量 返回协议头, 文本型
.局部变量 ADD_协议头, 类_POST数据类
.局部变量 提交协议头, 文本型
.局部变量 正则, 正则表达式类

域名 ＝ 文本_取出中间文本 (待解析链接, “https://”, “com”, , )
ADD_协议头.添加 (“user-agent”, “Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/100.0.4896.75 Safari/537.36”, )
提交协议头 ＝ ADD_协议头.获取协议头数据 ()
返回文本 ＝ 到文本 (网页_访问 (待解析链接, 0, , , , 提交协议头, , , , , , 真, , ))
正则.创建 (“src=” ＋ #引号 ＋ “/(.*?)” ＋ #引号 ＋ “ frameborder”, 返回文本, )
正则.取匹配文本 (1, )
src ＝ “/” ＋ 正则.取子匹配文本 (1, 1)
返回文本 ＝ 到文本 (网页_访问 (“https://” ＋ 域名 ＋ “com” ＋ src, 0, , , , 提交协议头, , , , , , 真, , ))
正则.创建 (“sign':'(.*?)'”, 返回文本, )
sign ＝ 正则.取子匹配文本 (1, 1)
ADD_协议头.添加 (“Referer”, “https://” ＋ 域名 ＋ “com/” ＋ src, )
提交协议头 ＝ ADD_协议头.获取协议头数据 ()
返回文本 ＝ 到文本 (网页_访问 (“https://” ＋ 域名 ＋ “com/ajaxm.php”, 1, “action=downprocess&signs=%3Fctdf&sign=” ＋ sign ＋ “&ves=1&websign=&websignkey=”, , , 提交协议头, , , , , , 真, , ))
url ＝ 文本_取出中间文本 (返回文本, “url” ＋ #引号 ＋ “:” ＋ #引号, #引号, , )
返回文本 ＝ 到文本 (网页_访问_对象 (“https://developer.lanzoug.com/file/” ＋ url, 0, , , , “User-Agent: Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/100.0.4896.75 Safari/537.36”, 返回协议头, , 真, , , , , , , , , , ))
返回协议头 ＝ 网页_协议头_取信息 (返回协议头, “Location”)
.如果真 (错误次数 ＝ 0)
    错误次数 ＝ 5
.如果真结束

.如果真 (返回协议头 ＝ “”)
    .计次循环首 (错误次数, )
        返回文本 ＝ 到文本 (网页_访问_对象 (“https://developer.lanzoug.com/file/” ＋ url, 0, , , , “User-Agent: Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/100.0.4896.75 Safari/537.36”, 返回协议头, , 真, , , , , , , , , , ))
        返回协议头 ＝ 网页_协议头_取信息 (返回协议头, “Location”)
        .如果真 (返回协议头 ≠ “”)
            跳出循环 ()
        .如果真结束
        延迟 (500)
    .计次循环尾 ()
.如果真结束
延迟 (2000)

信息框 (“解析成功奔放下载吧”, 64, “提示”, )
返回 (返回协议头)





.子程序 __启动窗口_创建完毕

华侨_加载皮肤_炫彩黑框 (, , )


.子程序 _按钮2_被单击

结束 ()

软件截图

软件链接

蓝奏云

下载

文件大小:1M

格式:EXE